SALV 1 : Normal Table Display

*&---------------------------------------------------------------------*
*& Report  ZOOPS_SALV_ALV1
*&
*&---------------------------------------------------------------------*
*&  This code will show you how to use the CL_SALV_TABLE to Generate the ALV
*&
*&---------------------------------------------------------------------*

REPORT  ZOOPS_SALV_ALV1.

*& Constant Declaration.
DATA LV_EBELN TYPE EKKO-EBELN.

*& Selection Screen
SELECTION-SCREEN BEGIN OF BLOCK A1 WITH FRAME TITLE TEXT-001.
SELECT-OPTIONS S_EBELN FOR LV_EBELN.
SELECTION-SCREEN END OF BLOCK A1.

CLASS CL_DATA DEFINITION.

  PUBLIC SECTION.

*& Structure for Purchasing Document Header Table
    TYPES : BEGIN OF TY_EKKO,
                      EBELN  TYPE EBELN,   "Purchasing Document Number
                      BUKRS TYPE BUKRS,   "Company Code
                      BSTYP  TYPE EBSTYP,  "Purchasing Document Category
                      BSART  TYPE ESART,   "Purchasing Document Type
                      BEDAT  TYPE EBDAT,   "Purchasing Document Date
            END OF TY_EKKO,

*& Structure for Purchasing Document Item Table
            BEGIN OF TY_EKPO,
              EBELN  TYPE EBELN,      "Purchasing Document Number
              EBELP  TYPE EBELP,       "Item Number of Purchasing Document
              MATNR  TYPE MATNR,   "Material Number
              MENGE  TYPE BSTMG,   "Purchase Order Quantity
              MEINS  TYPE BSTME,     "Purchase Order Unit of Measure
              NETPR  TYPE BPREI,      "Net Price in Purchasing Document (in Document Currency)
           END OF TY_EKPO.

*& Final Output stucture
    TYPES : BEGIN OF TY_FINAL,
                     EBELN  TYPE EBELN,   "Purchasing Document Number
                     BSART  TYPE ESART,   "Purchasing Document Type
                     BEDAT  TYPE EBDAT,   "Purchasing Document Date
                     MATNR TYPE MATNR,   "Material Number
                     MENGE TYPE BSTMG,   "Purchase Order Quantity
                     MEINS TYPE BSTME,   "Purchase Order Unit of Measure
                    NETPR TYPE BPREI,   "Net Price in Purchasing Document (in Document Currency)
               END OF TY_FINAL.

*& Internal Table Declration
    DATA : GT_EKKO  TYPE TABLE OF TY_EKKO INITIAL SIZE 1,
                 GT_EKPO  TYPE TABLE OF TY_EKPO INITIAL SIZE 1,
                 GT_FINAL TYPE TABLE OF TY_FINAL INITIAL SIZE 1.

*& Workarea Declaration.
    DATA : GS_FINAL TYPE TY_FINAL,
                 GS_EKKO  TYPE TY_EKKO,
                 GS_EKPO  TYPE TY_EKPO.

*& ALV Reference
    DATA : LO_ALV TYPE REF TO CL_SALV_TABLE.

*& Declare Methods for Get Data and Display Data
    METHODS : GET_DATA,     "Get data from Data base.
                          GET_POP_DATA, "Populate Final Display Data
                          DISPLAY.      "Display Data

ENDCLASS.

CLASS CL_DATA IMPLEMENTATION.

*&This Method is used to Get data from Data base
  METHOD GET_DATA.

    SELECT  EBELN
                    BUKRS
                    BSTYP
                    BSART
                    BEDAT
        FROM EKKO INTO TABLE GT_EKKO WHERE EBELN IN S_EBELN.

    IF GT_EKKO[] IS NOT INITIAL.
      SORT GT_EKKO BY EBELN.
    ELSE.
      MESSAGE 'Data not Found' TYPE 'E'.
    ENDIF.

    IF GT_EKKO[] IS NOT INITIAL.

      SELECT  EBELN
                      EBELP
                      MATNR
                      MENGE
                      MEINS
                      NETPR
         FROM EKPO INTO TABLE GT_EKPO FOR ALL ENTRIES IN GT_EKKO
         WHERE EBELN EQ GT_EKKO-EBELN.

    ENDIF.

  ENDMETHOD.

*& This Method is used to Populate final display Data
  METHOD GET_POP_DATA.

    LOOP AT GT_EKPO INTO GS_EKPO.

      GS_FINAL-EBELN = GS_EKPO-EBELN.
      GS_FINAL-MATNR = GS_EKPO-MATNR.
      GS_FINAL-MENGE = GS_EKPO-MENGE.
      GS_FINAL-MEINS = GS_EKPO-MEINS.
      GS_FINAL-NETPR = GS_EKPO-NETPR.

      CLEAR GS_EKKO.
      READ TABLE GT_EKKO INTO GS_EKKO WITH KEY EBELN = GS_EKPO-EBELN.
      IF SY-SUBRC EQ 0.
        GS_FINAL-BSART = GS_EKKO-BSART.
        GS_FINAL-BEDAT = GS_EKKO-BEDAT.
      ENDIF.

      APPEND GS_FINAL TO GT_FINAL.
      CLEAR GS_FINAL.

    ENDLOOP.

  ENDMETHOD.

*& This Method is used to Display Data
  METHOD DISPLAY.

*& We call the Factory Method to get the instance of the ALV.

    TRY.
        CALL METHOD CL_SALV_TABLE=>FACTORY
*      EXPORTING
*        LIST_DISPLAY   = IF_SALV_C_BOOL_SAP=>FALSE
*        R_CONTAINER    =
*        CONTAINER_NAME =
      IMPORTING
        R_SALV_TABLE    = LO_ALV
          CHANGING
            T_TABLE     = GT_FINAL
            .
      CATCH CX_SALV_MSG .
    ENDTRY.

*& Here we will call the display method to get the output on the screen
    LO_ALV->DISPLAY( ).

  ENDMETHOD.

ENDCLASS.

*& Start of Selection
START-OF-SELECTION.

*& Refence for Cl_DATA
DATA : LO_CL_DATA TYPE REF TO CL_DATA.

*& Object for CL_DATA Class.
CREATE OBJECT LO_CL_DATA.

*& Call the GET_DATA Method.
LO_CL_DATA->GET_DATA( ).

*& Call the GET_POP_DATA Method.
LO_CL_DATA->GET_POP_DATA( ).

*& Call the DISPLAY Method.
LO_CL_DATA->DISPLAY( ).

Out Put:

Download Sour code in PDF Format.
Download Sour code in Notepad.